VBS实现GB2312转Unicode

今天写了一个类似于下面的程序：

Dim http
Set http = CreateObject("msxml2.xmlhttp")
http.open "GET","http://www.sina.com.cn/",False
http.send
WScript.Echo http.responseText

但是却发现返回的中文都是乱码，看了一下发现新浪的编码竟然是gb2312的，汗，现在都是utf-8编码的时代了。responseText对utf-8编码支持得很好，但是如果是gb2312编码就会返回乱码，有时甚至会报错。无奈，只好用responseBody然后自己转码。

Dim http
Set http = CreateObject("msxml2.xmlhttp")
http.open "GET","http://www.sina.com.cn/",False
http.send
WScript.Echo GB2312ToUnicode(http.responseBody)

于是就要自己写一个GB2312ToUnicode函数，用ado很容易实现：

Function GB2312ToUnicode(str)
    With CreateObject("adodb.stream")
        .Type = 1 : .Open
        .Write str : .Position = 0
        .Type = 2 : .Charset = "gb2312"
        GB2312ToUnicode = .ReadText : .Close
    End With
End Function

这样返回的就是VBS字符串默认的Unicode编码了，不过用ado不能显示我鬼使神差的VBS水平，于是自己根据“算法”再写了一个：

Function GB2312ToUnicode(str)
    length = LenB(str) : out = ""
    For i = 1 To length
        c = AscB(MidB(str,i,1))
        If c <= 127 Then
            out = out & Chr(c)
        Else
            i = i + 1
            d = Hex(AscB(MidB(str,i,1)))
            c = "&H" & Hex(c) & d
            out = out & Chr(c)
        End If
    Next
    GB2312ToUnicode = out
End Function

只可惜效率太低，就当练练手吧。

随机文章:

1. iesetup.exe无法找到入口
2. 在Windows下源码编译PHP
3. 利用WMI打造完美“三无”后门（序章）
4. WMI工具：WMI Event Registration Tool
5. bbPress Nginx Rewrite

这篇文章发布于 2010年11月9日，星期二，14:20，归类于 程序设计。 您可以跟踪这篇文章的评论通过 RSS 2.0 feed。 您可以留下评论，或者从您的站点trackback。