VBS ByRef和ByVal参数

翻译自 MSDN VBScript 文档《ByRef and ByVal Parameters》，建议有能力的同学阅读原文。

当你调用一个过程或者函数的时候，每个参数都能以传址或者传值的方式传递。当一个参数以传址的方式传递时，在调用的过程中变量的值可以被改变，这个改变在调用过程结束之后仍然持续。当一个参数以传值的方式传递时，在调用的过程中对变量值的任何改变都不会在调用过程结束之后持续。

在一个 Sub 或者 Function 声明中，每一个参数都可以指定为 ByRef 或者 ByVal。如果两者都没有指定，默认为 ByRef。

如果指定为 ByVal，那么在调用过程中对应的参数总是以传值的方式传递。

如果指定为 ByRef 或者两个都不指定，那么在调用过程中参数以传址的方式传递。如果参数被小括号括起来，并且小括号并不属于参数列表，那么参数以传值的方式传递。当传递的变量是类的参数时，参数也以传值的方式传递。除此之外，参数以传址的方式传递。

指定 ByRef 和 ByVal

在下面这个例子中， MyParam 变量加上了 ByRef 关键字。在调用过程时，变量 MyArg 的引用被传递。当过程改变 MyParam 的值时，它同时也改变了 MyArg 的值。局部变量 MyParam 是全局变量 MyArg 的一个别名。

Sub TestSub(ByRef MyParam) 
    MyParam = 5
End Sub 

Dim MyArg 
MyArg = 123

TestSub MyArg
' MyArg 被 TestSub 过程改成 5.
' https://demon.tw

在下面一个例子中使用的是 ByVal 关键字，因此参数以传值的方式传递。过程改变了 MyParam 变量的值，然而 MyArg 变量的值保持不变。

Sub TestSub(ByVal MyParam) 
    MyParam = 5
End Sub 

Dim MyArg 
MyArg = 123
TestSub MyArg
' MyArg 仍然是 123.
' https://demon.tw

默认为 ByRef

如果没有明确指定 ByRef 或者 ByVal，那么默认为 ByRef。在这个例子， MyParam 为 ByRef，因为没有指定 ByRef 或者 ByVal。

Sub TestSub(MyParam)
    MyParam = 5
End Sub 

Dim MyArg 
MyArg = 123
TestSub MyArg
' MyArg 被 TestSub 过程改成 5.
' https://demon.tw

ByRef 参数以传值方式传递

在下列情况为真，被指定为 ByRef 的参数仍然能以传值方式传递：

• 参数在小括号中，并且小括号不属于参数列表；
• 被传递的参数是类中的变量；
• 被传递的参数不是变量，例如，12。

小括号中的参数

如果被小括号括起来，被指定为 ByRef 的参数仍然能够以传值的方式传递。如下面这个例子演示的一样。

Sub TestSub(ByRef MyParam) 
    MyParam = 5
End Sub

Dim MyArg
MyArg = 123
TestSub (MyArg)
' MyArg 仍然是 123.
' https://demon.tw

一个 ByRef 参数以传值的方式传递，如果它被小括号括起来，并且小括号不属于参数列表。

在下列情况下，小括号属于参数列表：

• 语句是一个将返回值赋值给变量的函数调用；
• 语句使用了 Call 关键字。（Call 关键字可以选择性使用，在调用过程或者没有将返回值赋值的函数时）

在下面的例子中，第二次调用 TestFunction 函数时将返回值赋值给了变量。因此在这次调用中，将参数列表括起来的小括号并不导致 ByRef 参数以传值的方式传递。

Function TestFunction(ByRef MyParam) 
    TestFunction = MyParam * 2
    MyParam = 5
End Function

Dim MyArg, Result 
MyArg = 123

TestFunction (MyArg)
' MyArg 仍然是 123.

Result = TestFunction (MyArg)
' MyArg 被改成 5.
' https://demon.tw

在下面的例子中使用了 Call 关键字，因此将参数列表括起来的小括号并不导致 ByRef 参数以传值的方式传递。

Sub TestSub(ByRef MyParam) 
    MyParam = 5
End Sub

Dim MyArg
MyArg = 123

Call TestSub ((MyArg))
' MyArg 仍然是 123.

Call TestSub (MyArg)
' MyArg 被改成 5.
' https://demon.tw

下面的例子中的函数有两个 ByRef 参数，在函数调用中，一个参数以传值的方式传递，另一个参数以传址的方式传递。

Function TestFunction(MyParam1, MyParam2) 
    ' 两个参数都是 ByRef, 因为没有指定 ByRef 和 ByVal
    TestFunction = MyParam1 * MyParam2
    MyParam1 = 5
    MyParam2 = 6
End Function

Dim MyArg1, MyArg2, Result
MyArg1 = 123
MyArg2 = 124

Result = TestFunction ((MyArg1), MyArg2)
' MyArg1 仍然是 123.
' MyArg2 被改成 6.
' https://demon.tw

类中的参数

如果传递的参数是类中的变量，那么 ByRef 参数以传值的方式传递。

在下面的例子中，MyParam 指定为 ByRef，在过程调用时使用了 cust.MyValue 作为参数，由于 cust.MyValue 在类中，所以参数以传值的方式传递。

Class Customer
    Public MyValue
End Class

Sub TestMethod (ByRef MyParam)
    MyParam = 5
End Sub

Dim cust
Set cust = New Customer
cust.MyValue = 123

TestMethod cust.MyValue
' cust.MyValue 仍然是 123.
' https://demon.tw

赞赏

微信赞赏支付宝赞赏

随机文章:

1. VC实现XP风格控件效果
2. EditPlus的VBS语法高亮
3. MySQL的Unicode支持
4. 通过SSH访问iPad
5. PT流量作弊工具之RatioMaster

这篇文章发布于 2012年02月7日，星期二，11:30，归类于 程序设计。 您可以跟踪这篇文章的评论通过 RSS 2.0 feed。 您可以留下评论，或者从您的站点trackback。