VBS中InputBox函数的返回值

标签: , , ,

你一定很熟悉InputBox函数,就像熟悉MsgBox函数一样。一般来说,刚开始接触VBS的时候,学会的第一个函数是MsgBox,而第二个就是InputBox。

如果用户单击确定或按下 ENTER,则 InputBox 函数返回文本框中的内容。如果用户单击取消,则函数返回一个零长度字符串 ("")。

这是参考手册对InputBox函数返回值的说明,简单而明了,还有必要专门写一篇文章来讨论?我知道你一定对标题不屑一顾,换成是我,我也一定会不屑一顾,如果我没有看到百度VBS吧里的一个帖子

关于Inputbox 疑惑
————————————————————————————
如果用户单击确定或按下 ENTER,则 InputBox 函数返回文本框中的内容。如果用户单击取消,则函数返回一个零长度字符串 ("")。
————————————————————————————
那如何区分用户是没有输入字符按了“确定”
还是按了“取消”呢?
有些时候想传入空字符的,而有些时候想取消输入

按照参考手册的说法,无论是用户没有输入字符按了“确定”,还是按了“取消”,函数的返回值都是零长度字符串""。这样看来,似乎没有办法区分用户是没有输入字符按了“确定”,还是按了“取消”。

我也以为这是无法实现的,但是下面却有人给出了解决方案:

Str=InputBox("???")
If Str="wffheu" Then MsgBox("a")
Else if Str=False Then "您按。。。取消"
End If

虽然有语法错误,但是用False的确可以区分出“确定”和“取消”。为什么呢?因为如果用户单击取消,InputBox返回的并不是一个零长度的字符串"",而是Empty

用一个简单的程序就可以测试出来:

str = InputBox("Enter a string")
MsgBox TypeName(str)

当没有输入字符直接按“确定”时输出String,而按“取消”时输出Empty。于是,似乎可以这样来判断到底是“确定”还是“取消”:

str = InputBox("Enter a string")
If str = Empty Then
    MsgBox "Cancel"
Else
    MsgBox "OK"
End If

只可惜上面的代码是错的,无论按下“确定”还是“取消”,都会输出Cancel。因为无论是"" = Empty(比较前Empty会隐式转化成"")还是Empty = Empty都会返回真,正确的方法是用IsEmpty来判断:

str = InputBox("Enter a string")
If IsEmpty(str) Then
    MsgBox "Cancel"
Else
    MsgBox "OK"
End If

再说说为什么可以用False来判断,"" = False返回假(比较前False会隐式转换成字符串"False"),而Empty = False返回真,于是可以判断。

看来文档写的也不一定是对的,尽信文档,不如无文档。

赞赏

微信赞赏支付宝赞赏

随机文章:

  1. 暴风一号病毒VBS源码解密
  2. 魔兽全屏补丁 魔兽宽屏补丁
  3. Windows下用TCC编译Lua源码
  4. 批处理技术内幕:重定向与管道
  5. VBS伪造HTTP-REFERER(二)

2 条评论 发表在“VBS中InputBox函数的返回值”上

  1. Zero说道:

    ask = “Hey, What’s your name?”
    title = “Who are you?”
    answer = InputBox (ask,tile)

    If answer = vbEmpty Then
    MsgBox “You want to cancel? Fine!”
    WScript.Quit
    ElseIf answer = “” Then

    MsgBox “You want to stay slient!”
    Else

    MsgBox “Welcome ” & answer & “!”
    End If

    这样可以么?

  2. 人士军爷说道:

    代码写很不错,简单易懂,老衲学习了。

留下回复