用VBS下载国家地理每日一图

国家地理的每日一图栏目很不错，常有一些精彩的照片。

写个VBS脚本下载之并重命名为日期加上照片标题。

都是正则表达式，而且没有写注释的习惯，很乱。

Option Explicit
Const url = "http://photography.nationalgeographic.com/" &_
"photography/photo-of-the-day/"
Dim http, ado
Dim html, image_url, image_name, image_time
Dim regex, matches, match

Set http = CreateObject("Msxml2.XMLHTTP")
Set ado = CreateObject("Adodb.Stream")
Set regex = New RegExp

http.open "GET",url,False
http.send
html = http.responseText

regex.Global = True

regex.Pattern = "<div class=""primary_photo"">([\s\S]+?)</div>"
Set matches = regex.Execute(html)
For Each match In matches
	image_url = match.Submatches(0)
Next

regex.Pattern = "<img src=""(.+?)"" [\s\S]+>"
Set matches = regex.Execute(image_url)
For Each match In matches
	image_url = match.Submatches(0)
Next

regex.Pattern = "<h1>(.+)</h1>"
Set matches = regex.Execute(html)
For Each match In matches
	image_name = match.Submatches(0)
Next

regex.Pattern = "<.+?>"
Set matches = regex.Execute(image_name)
For Each match In matches
	image_name = Replace(image_name, match, "")
Next

regex.Pattern = "<p class=""publication_time"">(.+?)</p>"
Set matches = regex.Execute(html)
For Each match In matches
	image_time = match.Submatches(0)
Next

http.open "GET",image_url,False
http.send

ado.Type = 1
ado.Open
ado.Write http.responseBody
ado.SaveToFile image_time & " " & image_name & ".jpg", 2
ado.Close

随机文章:

1. 在Raspberry Pi 2树莓派2上安装Node.js
2. 115网盘真实下载地址解析工具及其原理（VBS版）
3. VBS获取文件的SDDL字符串
4. 远程桌面连接用户名密码错误的解决方法
5. C#清除WebBrowser的Cookie缓存

这篇文章发布于 2010年10月16日，星期六，10:38，归类于 我的作品。 您可以跟踪这篇文章的评论通过 RSS 2.0 feed。 您可以留下评论，或者从您的站点trackback。