用VBS实现繁体中文和简体中文转换

Word 语言工具中有中文简繁转换功能，但是不能批量进行，所以写了一个实现繁体中文和简体中文相互转换 VBS 类。

Class TCSCConverter
    Private Word, Doc
    
    'Author: Demon
    'Date: 2011/12/13
    'Website: https://demon.tw

    Private Sub Class_Initialize()
        Set Word = CreateObject("Word.Application")
    End Sub
    
    Private Sub Class_Terminate()
        Word.Quit
        Set Word = Nothing
    End Sub
    
    'Traditional Chinese To Simplified Chinese
    Public Function TC2SC(str)
        Set Doc = Word.Documents.Add
        Word.Selection.TypeText str
        Doc.Range.TCSCConverter 1, True
        TC2SC = Replace(Doc.Range.Text, vbCr, vbCrLf)
        TC2SC = Left(TC2SC, Len(TC2SC) - 2)
        Doc.Saved = True
        Doc.Close
        Set Doc = Nothing
    End Function
    
    'Simplified Chinese To Traditional Chinese
    Public Function SC2TC(str)
        Set Doc = Word.Documents.Add
        Word.Selection.TypeText str
        Doc.Range.TCSCConverter 0, True, True
        SC2TC = Replace(Doc.Range.Text, vbCr, vbCrLf)
        SC2TC = Left(SC2TC, Len(SC2TC) - 2)
        Doc.Saved = True
        Doc.Close
        Set Doc = Nothing
    End Function
    
End Class

示例代码：

Set TCSC = New TCSCConverter
WScript.Echo TCSC.SC2TC("我下面给你吃")
WScript.Echo TCSC.TC2SC("我下麵給你吃")
WScript.Echo TCSC.SC2TC("我干妹妹的故事")
WScript.Echo TCSC.TC2SC("我乾妹妹的故事")

参考链接：发布VBS版汉字简繁体互换工具Chs2cht.vbs

参考链接：VBS 调用 TCSCConverter 进行繁简转换（内容、文件名）

参考链接：UMU Script 之 TCSCConverter – 批量文件（夹）名化繁为简

随机文章:

1. 使用正确版本的XMLHTTP
2. VBS中LoadPicture函数的正确用法
3. BEncode Editor——BT种子文件修改利器
4. 外网SSH远程访问OpenWrt
5. 对VBS效率的再思考——处理二进制数据

这篇文章发布于 2011年11月1日，星期二，21:14，归类于 我的作品。 您可以跟踪这篇文章的评论通过 RSS 2.0 feed。 您可以留下评论，或者从您的站点trackback。