VBS访问剪贴板的几种方法

最常见的是InternetExplorer.Application对象，网上一搜一大把。

Set IE = CreateObject("InternetExplorer.Application")
IE.Navigate("about:blank")
Set clipboard = IE.document.parentWindow.clipboardData
'SetData设置剪切板的内容
clipboard.SetData "text", "忘记了，喜欢一个人的感觉"
'GetData获取剪切板的内容
WScript.Echo clipboard.GetData("text")
IE.Quit

实践证明，网上一搜一大把的代码一般不是好代码。SetData方法其实是和IE浏览器的设置有关的。

IE8的默认设置是Prompt，所以运行上面那个脚本的时候会弹出一个对话框，如果这是成Disable，那么这个脚本就无法设置剪贴板内容了（获取不受影响）。

这种没有保证的代码还是少用一些的好，在Windows 7下可以用clip.exe来设置剪贴板的内容，获取的话还是用IE就行了。

Dim WshShell
set WshShell = CreateObject("wscript.Shell")
str = "忘记了，喜欢一个人的感觉"
WshShell.Run "cmd.exe /c echo " & str & " | clip",0,False

用Word.Application也可以设置和获取剪贴板内容

'设置剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.Text = "忘记了，喜欢一个人的感觉"
Word.Selection.Copy
Word.Quit False

'获取剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.PasteAndFormat(wdFormatPlainText)
Word.Selection.WholeStory
str = Word.Selection.Text
Word.Quit False
WScript.Echo str

最神奇的是用Microsoft Forms 2.0 Object Library。

'设置剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
TextBox.Text = "忘记了，喜欢一个人的感觉"
TextBox.SelStart = 0
TextBox.SelLength = TextBox.TextLength
TextBox.Copy

'获取剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
If TextBox.CanPaste Then
    TextBox.Paste
    WScript.Echo TextBox.Text
End If

参考链接：

1. [UMU WSH 教程](30) 访问剪贴板
2. [UMU WSH 教程](32) 访问剪贴板（2）

随机文章:

1. 快捷方式都以IE打开的解决方法
2. 确定Windows XP到底是UCS-2的还是UTF-16的
3. VBS对象作为过程参数是ByVal还是ByRef？
4. TL-WR703N进入OpenWrt的Failsafe安全模式
5. 从Win32程序的主函数WinMain中获取命令行参数

这篇文章发布于 2010年11月4日，星期四，17:51，归类于 程序设计。 您可以跟踪这篇文章的评论通过 RSS 2.0 feed。 您可以留下评论，或者从您的站点trackback。