VBS访问剪贴板的几种方法

标签: , , ,

最常见的是InternetExplorer.Application对象,网上一搜一大把。

Set IE = CreateObject("InternetExplorer.Application")
IE.Navigate("about:blank")
Set clipboard = IE.document.parentWindow.clipboardData
'SetData设置剪切板的内容
clipboard.SetData "text", "忘记了,喜欢一个人的感觉"
'GetData获取剪切板的内容
WScript.Echo clipboard.GetData("text")
IE.Quit

实践证明,网上一搜一大把的代码一般不是好代码。SetData方法其实是和IE浏览器的设置有关的。

ie

IE8的默认设置是Prompt,所以运行上面那个脚本的时候会弹出一个对话框,如果这是成Disable,那么这个脚本就无法设置剪贴板内容了(获取不受影响)。

prompt

这种没有保证的代码还是少用一些的好,在Windows 7下可以用clip.exe来设置剪贴板的内容,获取的话还是用IE就行了。

Dim WshShell
set WshShell = CreateObject("wscript.Shell")
str = "忘记了,喜欢一个人的感觉"
WshShell.Run "cmd.exe /c echo " & str & " | clip",0,False

用Word.Application也可以设置和获取剪贴板内容

'设置剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.Text = "忘记了,喜欢一个人的感觉"
Word.Selection.Copy
Word.Quit False
'获取剪切板的内容
Dim Word
Set Word = CreateObject("Word.Application")
Word.Documents.Add
Word.Selection.PasteAndFormat(wdFormatPlainText)
Word.Selection.WholeStory
str = Word.Selection.Text
Word.Quit False
WScript.Echo str

最神奇的是用Microsoft Forms 2.0 Object Library。

'设置剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
TextBox.Text = "忘记了,喜欢一个人的感觉"
TextBox.SelStart = 0
TextBox.SelLength = TextBox.TextLength
TextBox.Copy
'获取剪切板的内容
Dim Form, TextBox
Set Form = CreateObject("Forms.Form.1")
Set TextBox = Form.Controls.Add("Forms.TextBox.1").Object
TextBox.MultiLine = True
If TextBox.CanPaste Then
    TextBox.Paste
    WScript.Echo TextBox.Text
End If

参考链接:

  1. [UMU WSH 教程](30) 访问剪贴板
  2. [UMU WSH 教程](32) 访问剪贴板(2)
赞赏

微信赞赏支付宝赞赏

随机文章:

  1. VBS读取文本文件函数ReadTextFile
  2. 用JavaScript读写二进制文件的另一种方法
  3. Ubuntu下安装系统库函数手册
  4. VBS字符串与UTF-16(Unicode)
  5. ___security_cookie

9 条评论 发表在“VBS访问剪贴板的几种方法”上

  1. jiwanqiang说道:

    vb我只能看懂,呵呵……不过写的不错!能发现好途径就是最好的!

  2. prophetk说道:

    上次问你 你又说没有 – –

  3. 法拉利BEYOND说道:

    Demon写的代码一般是完美的

  4. PopEye说道:

    不得不承认,Demon的搜索技术和写代码的水平一样的强大。

  5. ns0990说道:

    事实上以上代码没有一个是最合适的,有些电脑在装机后并没有office,甚至用不到office

  6. Yiven说道:

    如ns0990所说,依靠office控件并非完美方案,有没有办法通过win32 API来实现呢

  7. 如何在vba中获取剪切板的图片到image控件。我的目的是保存vba中的窗体截图。目前用的keybd_event模拟alt+PrintScreen键。也用了PrintWindow ,但是vba中窗体都没有hdc也没有hwnd

留下回复