VBS中字符串连接的效率问题

标签: , , , ,

字符串连接谁不会,还用得着写?没错,在VBS中连接字符串确实很简单,无非就是&和+,不过本文不是讨论&和+用法之间的区别,而是讨论字符串连接的效率问题,即样才能快速地连接字符串?

当然,对于少量的字符串连接,效率并没有对程序造成多大影响,现在让我们考虑一个极端的问题:将1到100000之间的所有数字连接成一个字符串。

最简单的解决方案是直接使用&连接:

begin = Timer
For i = 1 To 100000
    str = str & CStr(i)
Next
WScript.Echo str
finish = Timer
WScript.Echo finish - begin

但是这个程序在我电脑上需要运行60.648秒,效率太低。换一种方案,用数组来解决:

begin = Timer
Dim arr(100000)
For i = 1 To 100000
    arr(i) = i
Next
str = Join(arr, "")
WScript.Echo str
finish = Timer
WScript.Echo finish - begin

这次只用了0.742秒,大概快了60倍。在这个问题中数组的大小是可以事先确定的,如果不能预知数组的大小就必须使用动态数组。我水平比较低,不会用动态数组,有没有更简单的方法呢?答案是有,那就是字典:

begin = Timer
Set oDic = CreateObject("scripting.dictionary")
For i = 1 To 100000
    oDic.Add i, CStr(i)
Next
str = Join(oDic.Items, "")
WScript.Echo str
finish = Timer
WScript.Echo finish - begin

运行时间为1.593,是数组的2倍,但是还是比&快多了,而且用起来比数组方便。

总结:&连接符号的效率是比较低的,在连接少量字符串时可以使用,但是在大量字符串连接时应该使用Join函数+数组。

赞赏

微信赞赏支付宝赞赏

随机文章:

  1. WMI工具:WMI CIM Studio
  2. Msxml2.XMLHTTP和Msxml2.ServerXMLHTTP的区别
  3. 可以用CreateObject创建的WMI对象
  4. 在Windows下编译iconv
  5. PT流量作弊工具之PTLiar2

3 条评论 发表在“VBS中字符串连接的效率问题”上

  1. RandomOS说道:

    学习了。

  2. 怒云说道:

    呵呵,现在开始注意效了??

    唉,这输入框怎么不支持Home和End键

  3. 枫中残雪说道:

    如果没想错的话,应该是&分组解析的原因吧(个要想法而以)

留下回复