用VBS实现繁体中文和简体中文转换

标签: , , , , , ,

Word 语言工具中有中文简繁转换功能,但是不能批量进行,所以写了一个实现繁体中文和简体中文相互转换 VBS 类。

Class TCSCConverter
    Private Word, Doc
    
    'Author: Demon
    'Date: 2011/12/13
    'Website: http://demon.tw

    Private Sub Class_Initialize()
        Set Word = CreateObject("Word.Application")
    End Sub
    
    Private Sub Class_Terminate()
        Word.Quit
        Set Word = Nothing
    End Sub
    
    'Traditional Chinese To Simplified Chinese
    Public Function TC2SC(str)
        Set Doc = Word.Documents.Add
        Word.Selection.TypeText str
        Doc.Range.TCSCConverter 1, True
        TC2SC = Replace(Doc.Range.Text, vbCr, vbCrLf)
        TC2SC = Left(TC2SC, Len(TC2SC) - 2)
        Doc.Saved = True
        Doc.Close
        Set Doc = Nothing
    End Function
    
    'Simplified Chinese To Traditional Chinese
    Public Function SC2TC(str)
        Set Doc = Word.Documents.Add
        Word.Selection.TypeText str
        Doc.Range.TCSCConverter 0, True, True
        SC2TC = Replace(Doc.Range.Text, vbCr, vbCrLf)
        SC2TC = Left(SC2TC, Len(SC2TC) - 2)
        Doc.Saved = True
        Doc.Close
        Set Doc = Nothing
    End Function
    
End Class

示例代码:

Set TCSC = New TCSCConverter
WScript.Echo TCSC.SC2TC("我下面给你吃")
WScript.Echo TCSC.TC2SC("我下麵給你吃")
WScript.Echo TCSC.SC2TC("我干妹妹的故事")
WScript.Echo TCSC.TC2SC("我乾妹妹的故事")

参考链接:发布VBS版汉字简繁体互换工具Chs2cht.vbs

参考链接:VBS 调用 TCSCConverter 进行繁简转换(内容、文件名)

参考链接:UMU Script 之 TCSCConverter – 批量文件(夹)名化繁为简

随机文章:

  1. 用VBS实现Discuz论坛自动回帖程序
  2. VBS真的能实现多线程?
  3. bb_register_plugin_activation_hook函数——bbPress的BUG
  4. Perl常用的内置特殊变量
  5. VBS中Run和Exec的区别

4 条评论 发表在“用VBS实现繁体中文和简体中文转换”上

  1. 小池说道:

    例子举的真……恰当……

  2. gleox说道:

    例子,有内涵

  3. champion说道:

    lz……淫才

  4. 开源混蛋说道:

    依赖Word,知道OpenCC项目吗?

留下回复